Training a HyperNetwork on MNIST and FashionMNIST

Package Imports

using Lux, ADTypes, ComponentArrays, AMDGPU, LuxCUDA, MLDatasets, MLUtils, OneHotArrays,
      Optimisers, Printf, Random, Setfield, Statistics, Zygote

CUDA.allowscalar(false)

Loading Datasets

function load_dataset(::Type{dset}, n_train::Int, n_eval::Int, batchsize::Int) where {dset}
    imgs, labels = dset(:train)[1:n_train]
    x_train, y_train = reshape(imgs, 28, 28, 1, n_train), onehotbatch(labels, 0:9)

    imgs, labels = dset(:test)[1:n_eval]
    x_test, y_test = reshape(imgs, 28, 28, 1, n_eval), onehotbatch(labels, 0:9)

    return (DataLoader((x_train, y_train); batchsize=min(batchsize, n_train), shuffle=true),
        DataLoader((x_test, y_test); batchsize=min(batchsize, n_eval), shuffle=false))
end

function load_datasets(n_train=1024, n_eval=32, batchsize=256)
    return load_dataset.((MNIST, FashionMNIST), n_train, n_eval, batchsize)
end

load_datasets (generic function with 4 methods)

Implement a HyperNet Layer

function HyperNet(weight_generator::Lux.AbstractExplicitLayer,
        core_network::Lux.AbstractExplicitLayer)
    ca_axes = Lux.initialparameters(Random.default_rng(), core_network) |>
              ComponentArray |>
              getaxes
    return @compact(; ca_axes, weight_generator, core_network, dispatch=:HyperNet) do (x, y)
        # Generate the weights
        ps_new = ComponentArray(vec(weight_generator(x)), ca_axes)
        @return core_network(y, ps_new)
    end
end

HyperNet (generic function with 1 method)

Defining functions on the CompactLuxLayer requires some understanding of how the layer is structured, as such we don't recommend doing it unless you are familiar with the internals. In this case, we simply write it to ignore the initialization of the core_network parameters.

function Lux.initialparameters(rng::AbstractRNG, hn::CompactLuxLayer{:HyperNet})
    return (; weight_generator=Lux.initialparameters(rng, hn.layers.weight_generator),)
end

Create and Initialize the HyperNet

function create_model()
    # Doesn't need to be a MLP can have any Lux Layer
    core_network = Chain(FlattenLayer(), Dense(784, 256, relu), Dense(256, 10))
    weight_generator = Chain(Embedding(2 => 32), Dense(32, 64, relu),
        Dense(64, Lux.parameterlength(core_network)))

    model = HyperNet(weight_generator, core_network)
    return model
end

create_model (generic function with 1 method)

Define Utility Functions

const loss = CrossEntropyLoss(; logits=Val(true))

function accuracy(model, ps, st, dataloader, data_idx, gdev=gpu_device())
    total_correct, total = 0, 0
    st = Lux.testmode(st)
    cpu_dev = cpu_device()
    for (x, y) in dataloader
        x = x |> gdev
        y = y |> gdev
        target_class = onecold(cpu_dev(y))
        predicted_class = onecold(cpu_dev(model((data_idx, x), ps, st)[1]))
        total_correct += sum(target_class .== predicted_class)
        total += length(target_class)
    end
    return total_correct / total
end

accuracy (generic function with 2 methods)

Training

function train()
    model = create_model()
    dataloaders = load_datasets()

    dev = gpu_device()

    rng = Xoshiro(0)

    train_state = Training.TrainState(rng, model, Adam(3.0f-4); transform_variables=dev)

    ### Lets train the model
    nepochs = 10
    for epoch in 1:nepochs, data_idx in 1:2
        train_dataloader, test_dataloader = dataloaders[data_idx]

        stime = time()
        for (x, y) in train_dataloader
            x = x |> dev
            y = y |> dev
            (_, _, _, train_state) = Training.single_train_step!(
                AutoZygote(), loss, ((data_idx, x), y), train_state)
        end
        ttime = time() - stime

        train_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                train_dataloader, data_idx, dev) * 100;
            digits=2)
        test_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                test_dataloader, data_idx, dev) * 100;
            digits=2)

        data_name = data_idx == 1 ? "MNIST" : "FashionMNIST"

        @printf "[%3d/%3d] \t %12s \t Time %.5fs \t Training Accuracy: %.2f%% \t Test \
                 Accuracy: %.2f%%\n" epoch nepochs data_name ttime train_acc test_acc
    end

    println()

    for data_idx in 1:2
        train_dataloader, test_dataloader = dataloaders[data_idx]
        train_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                train_dataloader, data_idx, dev) * 100;
            digits=2)
        test_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                test_dataloader, data_idx, dev) * 100;
            digits=2)

        data_name = data_idx == 1 ? "MNIST" : "FashionMNIST"

        @printf "[FINAL] \t %12s \t Training Accuracy: %.2f%% \t Test Accuracy: \
                 %.2f%%\n" data_name train_acc test_acc
    end
end

train()

[  1/ 10] 	        MNIST 	 Time 70.84561s 	 Training Accuracy: 78.81% 	 Test Accuracy: 75.00%
[  1/ 10] 	 FashionMNIST 	 Time 0.02111s 	 Training Accuracy: 49.12% 	 Test Accuracy: 40.62%
[  2/ 10] 	        MNIST 	 Time 0.02303s 	 Training Accuracy: 74.71% 	 Test Accuracy: 65.62%
[  2/ 10] 	 FashionMNIST 	 Time 0.02245s 	 Training Accuracy: 61.91% 	 Test Accuracy: 68.75%
[  3/ 10] 	        MNIST 	 Time 0.02206s 	 Training Accuracy: 86.72% 	 Test Accuracy: 75.00%
[  3/ 10] 	 FashionMNIST 	 Time 0.02314s 	 Training Accuracy: 57.03% 	 Test Accuracy: 46.88%
[  4/ 10] 	        MNIST 	 Time 0.02341s 	 Training Accuracy: 89.06% 	 Test Accuracy: 84.38%
[  4/ 10] 	 FashionMNIST 	 Time 0.02249s 	 Training Accuracy: 60.64% 	 Test Accuracy: 43.75%
[  5/ 10] 	        MNIST 	 Time 0.02302s 	 Training Accuracy: 90.14% 	 Test Accuracy: 90.62%
[  5/ 10] 	 FashionMNIST 	 Time 0.04617s 	 Training Accuracy: 69.34% 	 Test Accuracy: 56.25%
[  6/ 10] 	        MNIST 	 Time 0.02139s 	 Training Accuracy: 93.16% 	 Test Accuracy: 93.75%
[  6/ 10] 	 FashionMNIST 	 Time 0.02201s 	 Training Accuracy: 72.36% 	 Test Accuracy: 59.38%
[  7/ 10] 	        MNIST 	 Time 0.02163s 	 Training Accuracy: 94.63% 	 Test Accuracy: 93.75%
[  7/ 10] 	 FashionMNIST 	 Time 0.02081s 	 Training Accuracy: 75.78% 	 Test Accuracy: 65.62%
[  8/ 10] 	        MNIST 	 Time 0.02230s 	 Training Accuracy: 94.34% 	 Test Accuracy: 87.50%
[  8/ 10] 	 FashionMNIST 	 Time 0.02126s 	 Training Accuracy: 73.34% 	 Test Accuracy: 59.38%
[  9/ 10] 	        MNIST 	 Time 0.02134s 	 Training Accuracy: 94.53% 	 Test Accuracy: 96.88%
[  9/ 10] 	 FashionMNIST 	 Time 0.02095s 	 Training Accuracy: 73.63% 	 Test Accuracy: 59.38%
[ 10/ 10] 	        MNIST 	 Time 0.03727s 	 Training Accuracy: 97.66% 	 Test Accuracy: 93.75%
[ 10/ 10] 	 FashionMNIST 	 Time 0.02758s 	 Training Accuracy: 77.73% 	 Test Accuracy: 68.75%

[FINAL] 	        MNIST 	 Training Accuracy: 92.68% 	 Test Accuracy: 84.38%
[FINAL] 	 FashionMNIST 	 Training Accuracy: 77.73% 	 Test Accuracy: 68.75%

Appendix

using InteractiveUtils
InteractiveUtils.versioninfo()

if @isdefined(LuxDeviceUtils)
    if @isdefined(CUDA) && LuxDeviceUtils.functional(LuxCUDADevice)
        println()
        CUDA.versioninfo()
    end

    if @isdefined(AMDGPU) && LuxDeviceUtils.functional(LuxAMDGPUDevice)
        println()
        AMDGPU.versioninfo()
    end
end

Julia Version 1.10.4
Commit 48d4fd48430 (2024-06-04 10:41 UTC)
Build Info:
  Official https://julialang.org/ release
Platform Info:
  OS: Linux (x86_64-linux-gnu)
  CPU: 48 × AMD EPYC 7402 24-Core Processor
  WORD_SIZE: 64
  LIBM: libopenlibm
  LLVM: libLLVM-15.0.7 (ORCJIT, znver2)
Threads: 4 default, 0 interactive, 2 GC (on 2 virtual cores)
Environment:
  JULIA_CPU_THREADS = 2
  JULIA_DEPOT_PATH = /root/.cache/julia-buildkite-plugin/depots/01872db4-8c79-43af-ab7d-12abac4f24f6
  LD_LIBRARY_PATH = /usr/local/nvidia/lib:/usr/local/nvidia/lib64
  JULIA_PKG_SERVER = 
  JULIA_NUM_THREADS = 4
  JULIA_CUDA_HARD_MEMORY_LIMIT = 100%
  JULIA_PKG_PRECOMPILE_AUTO = 0
  JULIA_DEBUG = Literate

CUDA runtime 12.5, artifact installation
CUDA driver 12.5
NVIDIA driver 555.42.6

CUDA libraries: 
- CUBLAS: 12.5.3
- CURAND: 10.3.6
- CUFFT: 11.2.3
- CUSOLVER: 11.6.3
- CUSPARSE: 12.5.1
- CUPTI: 2024.2.1 (API 23.0.0)
- NVML: 12.0.0+555.42.6

Julia packages: 
- CUDA: 5.4.3
- CUDA_Driver_jll: 0.9.2+0
- CUDA_Runtime_jll: 0.14.1+0

Toolchain:
- Julia: 1.10.4
- LLVM: 15.0.7

Environment:
- JULIA_CUDA_HARD_MEMORY_LIMIT: 100%

1 device:
  0: NVIDIA A100-PCIE-40GB MIG 1g.5gb (sm_80, 2.170 GiB / 4.750 GiB available)

---

This page was generated using Literate.jl.