Training a HyperNetwork on MNIST and FashionMNIST

Package Imports

using Lux, ADTypes, ComponentArrays, AMDGPU, LuxCUDA, MLDatasets, MLUtils, OneHotArrays,
      Optimisers, Printf, Random, Setfield, Statistics, Zygote

CUDA.allowscalar(false)

Loading Datasets

function load_dataset(::Type{dset}, n_train::Int, n_eval::Int, batchsize::Int) where {dset}
    imgs, labels = dset(:train)[1:n_train]
    x_train, y_train = reshape(imgs, 28, 28, 1, n_train), onehotbatch(labels, 0:9)

    imgs, labels = dset(:test)[1:n_eval]
    x_test, y_test = reshape(imgs, 28, 28, 1, n_eval), onehotbatch(labels, 0:9)

    return (DataLoader((x_train, y_train); batchsize=min(batchsize, n_train), shuffle=true),
        DataLoader((x_test, y_test); batchsize=min(batchsize, n_eval), shuffle=false))
end

function load_datasets(n_train=1024, n_eval=32, batchsize=256)
    return load_dataset.((MNIST, FashionMNIST), n_train, n_eval, batchsize)
end

load_datasets (generic function with 4 methods)

Implement a HyperNet Layer

function HyperNet(weight_generator::Lux.AbstractExplicitLayer,
        core_network::Lux.AbstractExplicitLayer)
    ca_axes = Lux.initialparameters(Random.default_rng(), core_network) |>
              ComponentArray |>
              getaxes
    return @compact(; ca_axes, weight_generator, core_network, dispatch=:HyperNet) do (x, y)
        # Generate the weights
        ps_new = ComponentArray(vec(weight_generator(x)), ca_axes)
        @return core_network(y, ps_new)
    end
end

HyperNet (generic function with 1 method)

Defining functions on the CompactLuxLayer requires some understanding of how the layer is structured, as such we don't recommend doing it unless you are familiar with the internals. In this case, we simply write it to ignore the initialization of the core_network parameters.

function Lux.initialparameters(rng::AbstractRNG, hn::CompactLuxLayer{:HyperNet})
    return (; weight_generator=Lux.initialparameters(rng, hn.layers.weight_generator),)
end

Create and Initialize the HyperNet

function create_model()
    # Doesn't need to be a MLP can have any Lux Layer
    core_network = Chain(FlattenLayer(), Dense(784, 256, relu), Dense(256, 10))
    weight_generator = Chain(Embedding(2 => 32), Dense(32, 64, relu),
        Dense(64, Lux.parameterlength(core_network)))

    model = HyperNet(weight_generator, core_network)
    return model
end

create_model (generic function with 1 method)

Define Utility Functions

const loss = CrossEntropyLoss(; logits=Val(true))

function accuracy(model, ps, st, dataloader, data_idx, gdev=gpu_device())
    total_correct, total = 0, 0
    st = Lux.testmode(st)
    cpu_dev = cpu_device()
    for (x, y) in dataloader
        x = x |> gdev
        y = y |> gdev
        target_class = onecold(cpu_dev(y))
        predicted_class = onecold(cpu_dev(model((data_idx, x), ps, st)[1]))
        total_correct += sum(target_class .== predicted_class)
        total += length(target_class)
    end
    return total_correct / total
end

accuracy (generic function with 2 methods)

Training

function train()
    model = create_model()
    dataloaders = load_datasets()

    dev = gpu_device()

    rng = Xoshiro(0)

    train_state = Training.TrainState(rng, model, Adam(3.0f-4); transform_variables=dev)

    ### Lets train the model
    nepochs = 10
    for epoch in 1:nepochs, data_idx in 1:2
        train_dataloader, test_dataloader = dataloaders[data_idx]

        stime = time()
        for (x, y) in train_dataloader
            x = x |> dev
            y = y |> dev
            (_, _, _, train_state) = Training.single_train_step!(
                AutoZygote(), loss, ((data_idx, x), y), train_state)
        end
        ttime = time() - stime

        train_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                train_dataloader, data_idx, dev) * 100;
            digits=2)
        test_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                test_dataloader, data_idx, dev) * 100;
            digits=2)

        data_name = data_idx == 1 ? "MNIST" : "FashionMNIST"

        @printf "[%3d/%3d] \t %12s \t Time %.5fs \t Training Accuracy: %.2f%% \t Test \
                 Accuracy: %.2f%%\n" epoch nepochs data_name ttime train_acc test_acc
    end

    println()

    for data_idx in 1:2
        train_dataloader, test_dataloader = dataloaders[data_idx]
        train_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                train_dataloader, data_idx, dev) * 100;
            digits=2)
        test_acc = round(
            accuracy(model, train_state.parameters, train_state.states,
                test_dataloader, data_idx, dev) * 100;
            digits=2)

        data_name = data_idx == 1 ? "MNIST" : "FashionMNIST"

        @printf "[FINAL] \t %12s \t Training Accuracy: %.2f%% \t Test Accuracy: \
                 %.2f%%\n" data_name train_acc test_acc
    end
end

train()

[  1/ 10] 	        MNIST 	 Time 68.90980s 	 Training Accuracy: 70.80% 	 Test Accuracy: 68.75%
[  1/ 10] 	 FashionMNIST 	 Time 0.02815s 	 Training Accuracy: 51.46% 	 Test Accuracy: 43.75%
[  2/ 10] 	        MNIST 	 Time 0.03049s 	 Training Accuracy: 77.15% 	 Test Accuracy: 81.25%
[  2/ 10] 	 FashionMNIST 	 Time 0.02966s 	 Training Accuracy: 59.18% 	 Test Accuracy: 65.62%
[  3/ 10] 	        MNIST 	 Time 0.02925s 	 Training Accuracy: 83.69% 	 Test Accuracy: 84.38%
[  3/ 10] 	 FashionMNIST 	 Time 0.02350s 	 Training Accuracy: 64.26% 	 Test Accuracy: 53.12%
[  4/ 10] 	        MNIST 	 Time 0.02457s 	 Training Accuracy: 88.38% 	 Test Accuracy: 93.75%
[  4/ 10] 	 FashionMNIST 	 Time 0.02427s 	 Training Accuracy: 63.38% 	 Test Accuracy: 53.12%
[  5/ 10] 	        MNIST 	 Time 0.02401s 	 Training Accuracy: 87.21% 	 Test Accuracy: 84.38%
[  5/ 10] 	 FashionMNIST 	 Time 0.02094s 	 Training Accuracy: 71.00% 	 Test Accuracy: 65.62%
[  6/ 10] 	        MNIST 	 Time 0.02087s 	 Training Accuracy: 92.48% 	 Test Accuracy: 93.75%
[  6/ 10] 	 FashionMNIST 	 Time 0.02151s 	 Training Accuracy: 69.82% 	 Test Accuracy: 59.38%
[  7/ 10] 	        MNIST 	 Time 0.02199s 	 Training Accuracy: 93.95% 	 Test Accuracy: 90.62%
[  7/ 10] 	 FashionMNIST 	 Time 0.02216s 	 Training Accuracy: 71.29% 	 Test Accuracy: 59.38%
[  8/ 10] 	        MNIST 	 Time 0.02150s 	 Training Accuracy: 93.16% 	 Test Accuracy: 90.62%
[  8/ 10] 	 FashionMNIST 	 Time 0.02096s 	 Training Accuracy: 76.86% 	 Test Accuracy: 71.88%
[  9/ 10] 	        MNIST 	 Time 0.02169s 	 Training Accuracy: 95.12% 	 Test Accuracy: 96.88%
[  9/ 10] 	 FashionMNIST 	 Time 0.04021s 	 Training Accuracy: 73.44% 	 Test Accuracy: 68.75%
[ 10/ 10] 	        MNIST 	 Time 0.02459s 	 Training Accuracy: 96.88% 	 Test Accuracy: 96.88%
[ 10/ 10] 	 FashionMNIST 	 Time 0.02115s 	 Training Accuracy: 77.83% 	 Test Accuracy: 59.38%

[FINAL] 	        MNIST 	 Training Accuracy: 96.88% 	 Test Accuracy: 96.88%
[FINAL] 	 FashionMNIST 	 Training Accuracy: 77.83% 	 Test Accuracy: 59.38%

Appendix

using InteractiveUtils
InteractiveUtils.versioninfo()

if @isdefined(LuxDeviceUtils)
    if @isdefined(CUDA) && LuxDeviceUtils.functional(LuxCUDADevice)
        println()
        CUDA.versioninfo()
    end

    if @isdefined(AMDGPU) && LuxDeviceUtils.functional(LuxAMDGPUDevice)
        println()
        AMDGPU.versioninfo()
    end
end

Julia Version 1.10.5
Commit 6f3fdf7b362 (2024-08-27 14:19 UTC)
Build Info:
  Official https://julialang.org/ release
Platform Info:
  OS: Linux (x86_64-linux-gnu)
  CPU: 48 × AMD EPYC 7402 24-Core Processor
  WORD_SIZE: 64
  LIBM: libopenlibm
  LLVM: libLLVM-15.0.7 (ORCJIT, znver2)
Threads: 4 default, 0 interactive, 2 GC (on 2 virtual cores)
Environment:
  JULIA_CPU_THREADS = 2
  JULIA_DEPOT_PATH = /root/.cache/julia-buildkite-plugin/depots/01872db4-8c79-43af-ab7d-12abac4f24f6
  LD_LIBRARY_PATH = /usr/local/nvidia/lib:/usr/local/nvidia/lib64
  JULIA_PKG_SERVER = 
  JULIA_NUM_THREADS = 4
  JULIA_CUDA_HARD_MEMORY_LIMIT = 100%
  JULIA_PKG_PRECOMPILE_AUTO = 0
  JULIA_DEBUG = Literate

CUDA runtime 12.5, artifact installation
CUDA driver 12.5
NVIDIA driver 555.42.6

CUDA libraries: 
- CUBLAS: 12.5.3
- CURAND: 10.3.6
- CUFFT: 11.2.3
- CUSOLVER: 11.6.3
- CUSPARSE: 12.5.1
- CUPTI: 2024.2.1 (API 23.0.0)
- NVML: 12.0.0+555.42.6

Julia packages: 
- CUDA: 5.4.3
- CUDA_Driver_jll: 0.9.2+0
- CUDA_Runtime_jll: 0.14.1+0

Toolchain:
- Julia: 1.10.5
- LLVM: 15.0.7

Environment:
- JULIA_CUDA_HARD_MEMORY_LIMIT: 100%

1 device:
  0: NVIDIA A100-PCIE-40GB MIG 1g.5gb (sm_80, 2.232 GiB / 4.750 GiB available)

---

This page was generated using Literate.jl.